General Clear and Reset Quick Access Folders in Windows 11

# Clear unpinned folders from Quick Access, using the Verbs() method
$RecentQuickAccessFolders = (0,0)
While ($RecentQuickAccessFolders) {
    $RecentQuickAccessFolders = (((New-Object -ComObject Shell.Application).Namespace("shell:::{679f85cb-0220-4080-b29b-5540cc05aab6}").Items() |
    where IsFolder -eq $true).Verbs() | where Name -Match "Remove from Quick access")
    If ($RecentQuickAccessFolders) { $RecentQuickAccessFolders.DoIt() }
}

(New-Object -ComObject Shell.Application).Namespace($env:USERPROFILE).Self.InvokeVerb('pintohome')

'******** This script collects the path data from the Pinned Folders part of Quick Access in Explorer and saves it to a textfile,
'********  and the %USERPROFILE% environment variable will be used in the paths where needed.
'******** WARNING: The textfile will be overwritten if it already exists. The output folder will be created if it doesn't exist.


'**** The filename of the textfile to be created/overwritten:
Const TXT_FILE = "QuickAccess.txt"

'**** The folderpath of the folder to move the resource file to, and create the textfile in, ending with a backslash:
Const DEST_PATH = "C:\tools\QuickAccess\"

'**** The name of the temporary dummy subfolder that will be created:
Const DUMMY_FOLDER = "Dummy"

'**** The part to append to %APPDATA% for defining the path to the folder that contains the resource file, ending with a backslash:
Const RES_FOLDER = "\Microsoft\Windows\Recent\AutomaticDestinations\"

'**** The filename of the resource file:
Const RES_FILE = "f01b4d95cf55d32a.automaticDestinations-ms"

Dim blnNotPinned, blnContinue
Dim i, j, k
Dim strResFolder, strResFilepath, strName, strPin, strUnpin, strUserprofile, strPath, strResult
Dim objFolderItem1, objFolderItem2, objVerb, objItems
Dim objShellApp, wshShell, fso

Set fso = CreateObject("Scripting.FileSystemObject")

' // create the destination folder if it doesn't exist //
If Not fso.FolderExists(DEST_PATH) Then fso.CreateFolder(DEST_PATH)

' // expand a few environment variables //
Set wshShell = WScript.CreateObject("WScript.Shell")
strUserprofile = wshShell.ExpandEnvironmentStrings("%USERPROFILE%")
strResFolder = wshShell.ExpandEnvironmentStrings("%APPDATA%") & RES_FOLDER
strResFilepath = strResFolder & RES_FILE
Set wshShell = Nothing

' // temporarily move the resource file //
If fso.FileExists(DEST_PATH & RES_FILE) Then fso.DeleteFile DEST_PATH & RES_FILE
fso.MoveFile strResFilepath, DEST_PATH

Set objShellApp = CreateObject("Shell.Application")

' // trigger a refresh to prevent the resource file from not always wanting to just regenerate itself automagically //
Set objFolderItem1 = objShellApp.NameSpace(DEST_PATH).Self
objFolderItem1.InvokeVerb("pintohome")
Set objFolderItem1 = objShellApp.Namespace("shell:::{679F85CB-0220-4080-B29B-5540CC05AAB6}").Items.Item(6)
objFolderItem1.InvokeVerb("unpinfromhome")

' // get the localized verb names for Pin + Unpin by comparing verb names of FolderItem objects for the Downloads folder //
Set objFolderItem1 = objShellApp.Namespace("shell:::{679F85CB-0220-4080-B29B-5540CC05AAB6}").Items.Item(1)
Set objFolderItem2 = objShellApp.NameSpace(objFolderItem1.Path).Self
j = objFolderItem1.Verbs.Count - 1
Do
  i = i + 1
  strName = objFolderItem1.Verbs.Item(i).Name
  strPin = objFolderItem2.Verbs.Item(i).Name
  If strName <> strPin Then Exit Do ' // found verb name for Pin //
Loop While i < j
Do
  i = i + 1
  strUnpin = objFolderItem1.Verbs.Item(i).Name
  strName = objFolderItem2.Verbs.Item(i + 1).Name
  If strUnpin <> strName Then Exit Do ' // found verb name for Unpin //
Loop While i < j
Set objFolderItem1 = Nothing
Set objFolderItem2 = Nothing

' // move the resource file back to its original location
fso.CopyFile DEST_PATH & RES_FILE, strResFolder, True
fso.DeleteFile DEST_PATH & RES_FILE

' // trigger an auto refresh of the Quick Access view in any open Explorer windows // **********************************
If Not fso.FolderExists(DEST_PATH & DUMMY_FOLDER) Then fso.CreateFolder(DEST_PATH & DUMMY_FOLDER)
Set objItems = objShellApp.Namespace("shell:::{679F85CB-0220-4080-B29B-5540CC05AAB6}").Items
i = objItems.Count
objShellApp.NameSpace(DEST_PATH & DUMMY_FOLDER).Self.InvokeVerb("pintohome")
blnContinue = True
j = 50
While j > 0 And blnContinue
  WScript.Sleep 150
  Set objItems = objShellApp.Namespace("shell:::{679F85CB-0220-4080-B29B-5540CC05AAB6}").Items
  If objItems.Count = i + 1 Then
    objItems.Item(i).InvokeVerb("unpinfromhome")
    k = 50
    While k > 0 And blnContinue
      WScript.Sleep 150
      Set objItems = objShellApp.Namespace("shell:::{679F85CB-0220-4080-B29B-5540CC05AAB6}").Items
      If objItems.Count = i Then
        blnContinue = False
      End If
      k = k - 1
    Wend
    blnContinue = False
  End If
  j = j - 1
Wend
Set objItems = Nothing
fso.DeleteFolder(DEST_PATH & DUMMY_FOLDER)

' // get the pinned folders //
blnContinue = False
j = Len(strUserprofile)
For Each objFolderItem1 In objShellApp.Namespace("shell:::{679F85CB-0220-4080-B29B-5540CC05AAB6}").Items
  blnNotPinned = True
  For Each objVerb In objFolderItem1.Verbs
    strName = objVerb.Name
    If strName = strUnpin Then
      blnNotPinned = False
      Exit For ' // found a pinned folder
    End If
    If strName = strPin Then Exit For ' // not a pinned folder //
  Next
  Set objVerb = Nothing
  If blnNotPinned Then Exit For ' // finished searching for pinned folders //
  strPath = objFolderItem1.Path
  If strUserprofile = Left(strPath, j) Then strPath = "%USERPROFILE%" & Right(strPath, Len(strPath) - j)
  If blnContinue Then
    strResult = strResult & vbCrLf & strPath
  Else
    strResult = strPath
    blnContinue = True
  End If
Next
Set objShellApp = Nothing
Set objFolderItem1 = Nothing

' // write the result to the textfile and overwrite it if it already exists //
Set objFile = fso.CreateTextFile(DEST_PATH & TXT_FILE)
objFile.Write strResult
objFile.Close

'******** This script collects the path data from a textfile to overwrite the Pinned Folders part of Quick Access in Explorer.
'********  WARNING: Any folders currently pinned to Quick Access will be unpinned so, please remember to verify the textfile.


'**** The filename of the textfile to be read:
Const TXT_FILE = "QuickAccess.txt"

'**** The folderpath of the folder to move the resource file to, and retrieve the textfile from, ending with a backslash:
Const SRC_PATH = "C:\tools\QuickAccess\"

'**** The part to append to %APPDATA% for defining the filepath of the resource file:
Const RES_FILEPATH = "\Microsoft\Windows\Recent\AutomaticDestinations\f01b4d95cf55d32a.automaticDestinations-ms"

'**** The part to append to %APPDATA% for defining the path to the Network Locations of This PC, ending with a backslash:
Const NL_FOLDER = "\Microsoft\Windows\Network Shortcuts\"

Dim arrInput
Dim blnNotFound
Dim i
Dim strAppData, strResFilepath, strNLFolder, strUserprofile, strPath, strP
Dim objFile, objItems, objFolderItem
Dim objShellApp, wshShell, fso

Set fso = CreateObject("Scripting.FileSystemObject")

' // read the lines from the textfile and store them as an array //
Set objFile = fso.OpenTextFile(SRC_PATH & TXT_FILE, 1)
arrInput = Split(objFile.ReadAll, vbCrLf)
objFile.Close
Set objFile = Nothing

' // expand a few environment variables //
Set wshShell = WScript.CreateObject("WScript.Shell")
strUserprofile = wshShell.ExpandEnvironmentStrings("%USERPROFILE%")
strAppData = wshShell.ExpandEnvironmentStrings("%APPDATA%")
strResFilepath = strAppData & RES_FILEPATH
strNLFolder = strAppData & NL_FOLDER
Set wshShell = Nothing

' // delete the resource file //
fso.DeleteFile strResFilepath
Set fso = Nothing

Set objShellApp = CreateObject("Shell.Application")

' // unpin the six pinned folders pinned by default //
Set objItems = objShellApp.Namespace("shell:::{679F85CB-0220-4080-B29B-5540CC05AAB6}").Items
For i = 5 To 0 Step -1
  objItems.Item(i).InvokeVerb("unpinfromhome")
Next
Set objItems = Nothing

' // pin all the folders as is specified by the contents of the textfile //
For Each strPath In arrInput
  If UCase(Left(strPath, 13)) = "%USERPROFILE%" Then strPath = strUserprofile & Right(strPath, Len(strPath) - 13)
  blnNotFound = True
  If Left(strPath, 2) = "\\" Then ' // hack-a-mole with the UNC path for making it work... maybe
    For Each objFolderItem In objShellApp.Namespace(strNLFolder).Items
      strP = objFolderItem.GetFolder.GetDetailsOf(objFolderItem, 194)
      If strPath & "\" = Left(strP, InStrRev(strP, "\")) Then
        blnNotFound = False
        objFolderItem.InvokeVerb("pintohome")
        Exit For ' // well played... lol
      End If
    Next
  End If
  If blnNotFound Then objShellApp.NameSpace(strPath).Self.InvokeVerb("pintohome")
Next