SeConv - SubtitleEdit's Command Line Tool BAT Samples

@echo off
setlocal EnableExtensions EnableDelayedExpansion

set "SECONV=D:\FLY\SubtitleEdit\seconv.exe"
set "REPORT=%~dp0encoding_report.txt"
set "JSON=%TEMP%\seconv_info.json"

> "%REPORT%" echo SRT ENCODING REPORT
>>"%REPORT%" echo Created: %date% %time%
>>"%REPORT%" echo.
>>"%REPORT%" echo File ^| Encoding
>>"%REPORT%" echo -------------------------------------------------------------------------------

for /r "%~dp0" %%F in (*.srt) do (
    echo Scanning: %%~nxF

    "%SECONV%" info "%%~fF" --json > "%JSON%" 2>nul

    set "ENCODING="

    for /f "delims=" %%A in ('findstr /C:"encoding" "%JSON%"') do (
        set "ENCODING=%%A"
    )

    set "ENCODING=!ENCODING:  "encoding": "=!"
    set "ENCODING=!ENCODING:"encoding": "=!"
    set "ENCODING=!ENCODING:",=!"

    >>"%REPORT%" echo %%~fF ^| !ENCODING!
)

del "%JSON%" 2>nul

echo.
echo Done.
echo Report: "%REPORT%"


set "INPUT=%~dp0encoding_report.txt"

set "TEMP_EN=srt_temp_en.txt"
set "TEMP_TR=srt_temp_tr.txt"

set "OUTPUT_EN=different_en.txt"
set "OUTPUT_TR=different_tr.txt"

findstr /i /l ".en.srt" "%INPUT%" > "%TEMP_EN%"
findstr /i /v /l /c:"utf-8 (with BOM)" "%TEMP_EN%" > "%OUTPUT_EN%"

findstr /i /l ".tr.srt" "%INPUT%" > "%TEMP_TR%"
findstr /i /v /l /c:"windows-1254" "%TEMP_TR%" > "%OUTPUT_TR%"

del "%TEMP_EN%" 2>nul
del "%TEMP_TR%" 2>nul


pause

@echo off
setlocal EnableExtensions EnableDelayedExpansion

set "SECONV=D:\FLY\SubtitleEdit\seconv.exe"

for /f "usebackq delims=|" %%F in ("different_en.txt") do (
    set "FILE=%%F"
    set "FILE=!FILE:~0,-1!"

    echo Converting: !FILE!
    "%SECONV%" "!FILE!" subrip --encoding:utf-8 --overwrite
)

echo.
echo All files converted.
pause

@echo off
setlocal EnableExtensions EnableDelayedExpansion

set "SECONV=D:\FLY\SubtitleEdit\seconv.exe"

for /f "usebackq delims=|" %%F in ("different_tr.txt") do (
    set "FILE=%%F"
    set "FILE=!FILE:~0,-1!"

    echo Converting: !FILE!
    "%SECONV%" "!FILE!" subrip --encoding:windows-1254 --overwrite
)

echo.
echo All files converted.
pause