batch script choose 1 or 2 registry setting

shoober420 · Nov 7, 2024

i was googling how to do a batch script choice by numbers, like 1 and 2. i came across a template and adjusted the settings to correlate with the choices desired.

Code:

ECHO off
cls
:start
ECHO.
ECHO 1. Print Latency
ECHO 2. Print Performance
set choice=
set /p choice=Press 1 for Latency / Press 2 for Performance
if not '%choice%'=='' set choice=%choice:~0,1%
if '%choice%'=='1' reg add "HKLM\SYSTEM\CurrentControlSet\Control\PriorityControl" /v "Win32PrioritySeparation" /t REG_DWORD /d "0x00000028" /f
if '%choice%'=='1' reg add "HKLM\SYSTEM\ControlSet001\Control\PriorityControl" /v "Win32PrioritySeparation" /t REG_DWORD /d "0x00000028" /f
if '%choice%'=='2' reg add "HKLM\SYSTEM\CurrentControlSet\Control\PriorityControl" /v "Win32PrioritySeparation" /t REG_DWORD /d "0x00000016" /f
if '%choice%'=='2' reg add "HKLM\SYSTEM\ControlSet001\Control\PriorityControl" /v "Win32PrioritySeparation" /t REG_DWORD /d "0x00000016" /f
ECHO "%choice%" is not valid, try again
ECHO.
goto start
:hello
ECHO Latency
goto end
:bye
ECHO Performance
goto end
:end

PAUSE

i wont be at a computer for another couple days. does this look like it will work, with 1 being Latency registry keys and 2 being Performance registry keys?

spapakons · Nov 7, 2024

I am not familiar with modern Command Prompt, if the syntax is correct, it should work. Back in good old MS-DOS the condition was
if errorlevel%== or similar.

Dronix · Nov 7, 2024

shoober420 said:
Performance registry keys?

I've made some modifications and this is what I got. I also added a return to default setting. Give it a try.

echo off
:: Created by Dronix7 07.11.2024 UpDated 07.11.2024
:_Start
mode con:cols=50 lines=17
color F0 & cls
echo.
echo 1. Latency Configuration
echo 2. Performance Configuration
echo 3. Standard Configuration
echo.
set choice=
set /p choice=. Select Item and Enter or Enter to Exit:
echo.
:: =================================================================================================================================================
if %choice% == 1 set Par="0x00000028" & set Message=The Latency Configuration Has Been Applied & goto :_Continue
if %choice% == 2 set Par="0x00000016" & set Message=The Performance Configuration Has Been Applied & goto :_Continue
if %choice% == 3 set Par="0x00000026" & set Message=The Standard Configuration Has Been Applied & goto :_Continue
echo Out Of Range. To Continue, Press Enter & echo. & pause & goto :_Start
:: =================================================================================================================================================
:_Continue
reg add "HKLM\SYSTEM\CurrentControlSet\Control\PriorityControl" /v "Win32PrioritySeparation" /t REG_DWORD /d "%Par%" /f
reg add "HKLM\SYSTEM\ControlSet001\Control\PriorityControl" /v "Win32PrioritySeparation" /t REG_DWORD /d "%Par%" /f & echo.
echo %Message%
:: =================================================================================================================================================
echo.
echo 0 - Continue Choosing
echo Enter - Exit
echo.
set Variant=
set /p Variant="Make Your Choice and Press Enter (0 or Enter): "
echo.
if "%Variant%"== "0" goto :_Start
if "%Variant%"==""
:: =================================================================================================================================================

Ready bat file - Selecting Items

shoober420 · Nov 7, 2024

@Dronix this looks amazing, i cant wait to try this in a couple days. very nice work

pseymour · Nov 7, 2024

You may want to consider using the built-in choice command, which can limit the user to choosing a valid option, rather than just typing in any value.

Batch:

echo.
echo 1. Latency Configuration
echo 2. Performance Configuration
echo 3. Standard Configuration
echo C. Cancel
echo.
choice /c 123C /m "Choose an option :"

if 4 EQU %ERRORLEVEL% (
   echo User chose to cancel.
) else if 3 EQU %ERRORLEVEL% (
   echo User chose option 3.
) else if 2 EQU %ERRORLEVEL% (
   echo User chose option 2.
) else if 1 EQU %ERRORLEVEL% (
   echo User chose option 1.
) else if 0 EQU %ERRORLEVEL% (
   echo User bailed out.
)

Dronix · Nov 7, 2024

pseymour said:
You may want to consider using the built-in choice command

I like what you've done, but I didn't understand where the sound comes from when selecting a value outside the selected range.

pseymour · Nov 7, 2024

Dronix said:
I like what you've done, but I didn't understand where the sound comes from when selecting a value outside the selected range.

It's a built-in handy beep feature, provided free of charge by Windows. :)

"If the user presses a key that is not a valid choice, choice sounds a warning beep."

choice

Reference article for the choice command, which prompts the user to select one item from a list of single-character choices in a batch program, and then returns the index of the selected choice.

learn.microsoft.com

Bree · Nov 7, 2024

pseymour said:
You may want to consider using the built-in choice command

I love using the CHOICE command. If (as I do) you ever want to use it for a batch file in the WinPE environment, such as a booting to a command prompt with a Windows install usb, then you need to copy C:\Windows\System32\choice.exe to the same folder on the usb as your batch file.

garlin · Nov 7, 2024

To expand on @pseymour's example, you should use call subroutines so your script is more readable.

Code:

@echo off

echo.
echo 1. Latency Configuration
echo 2. Performance Configuration
echo 3. Standard Configuration
echo C. Cancel
echo.
choice /c 123C /m "Choose an option :"

if 4 EQU %ERRORLEVEL% (
   echo User chose to cancel.
) else if 3 EQU %ERRORLEVEL% (
   call :standard
) else if 2 EQU %ERRORLEVEL% (
   call :performance
) else if 1 EQU %ERRORLEVEL% (
   call :latency
) else if 0 EQU %ERRORLEVEL% (
   echo User bailed out.
)

goto :eof

:latency
echo User chose Latency option.
echo reg add ...
exit /b

:performance
echo User chose Performance option.
echo reg add ...
exit /b

:standard
echo User chose Standard option.
echo reg add ...
exit /b

Bizarre · Nov 7, 2024

@shoober420, you might find this article interesting.

Win32PrioritySeparation - Understanding How the Values Impact Your Performance - XBitLabs

Changing your Win32PrioritySeparation value in the registry has become a staple in the optimization process of your PC, but unfortunately, a lot of people editing their values rely on guesswork or internet myths. Using this or that value just because someone in a Reddit thread mentioned it is...

www.xbitlabs.com

shoober420 · Jan 1, 2025

i found the time to finish the Thread Quantum script

windows11-scripts/ThreadQuantum.bat at main · shoober420/windows11-scripts

Windows 11 Scripts. Contribute to shoober420/windows11-scripts development by creating an account on GitHub.

github.com

batch script choose 1 or 2 registry setting

Well-known member

My Computer My Computer

At a glance

Well-known member

My Computers My Computers

At a glance

At a glance

Well-known member

My Computer My Computer

At a glance

Well-known member

My Computer My Computer

At a glance

We summon thee from the dead, old threads!

My Computer My Computer

At a glance

Well-known member

My Computer My Computer

At a glance

We summon thee from the dead, old threads!

My Computer My Computer

At a glance

Well-known member

My Computers My Computers

At a glance

At a glance

Well-known member

My Computer My Computer

At a glance

Well-known member

My Computer My Computer

At a glance

Well-known member

My Computer My Computer

At a glance

Similar threads

My Computer

My Computers

My Computer

My Computer

My Computer

My Computer

My Computer

My Computers

My Computer

My Computer

My Computer