Doing a clean install of Windows? Here's a batch file to make an image backup and driver backup first.

:: *****************************
:: * Quick Backup              *
:: * by Hannes Sehestedt       *
:: * Last update June 20, 2025 *
:: *****************************

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: This batch file will make a backup copy of all drivers installed on your     ::
:: system and then it will use WBADMIN to make a disk image backup of your      ::
:: system (C:, Recovery partition, EFI Partition) to a drive that you will      ::
:: specify. WBADMIN will only backup to the root of a drive creating a folder   ::
:: by the name of WindowsImageBackup. Another annoyance is that sets            ::
:: permissions on that folder in a way that makes easy access difficult. So,    ::
:: to work around this, after the backup is created this batch file will give   ::
:: the currently logged on user ownership and permission to access this folder. ::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::


@echo off
setlocal enabledelayedexpansion
setlocal enableextensions
cd /d %~dp0

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Check to see if this batch file is being run as Administrator. If it is not, then rerun the batch file ::
:: automatically as admin and terminate the intial instance of the batch file.                            ::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

(Fsutil Dirty Query %SystemDrive%>Nul)||(PowerShell start """%~f0""" -verb RunAs & Exit /B)

::::::::::::::::::::::::::::::::::::::::::::::::
:: End Routine to check if being run as Admin ::
::::::::::::::::::::::::::::::::::::::::::::::::


:: Ask for the drive letter to which backups should be saved.

echo Enter the drive letter to which we should backup the system and save drivers.
echo Please enter the letter only (no colon).
echo.
set /p Target="Enter the target drive letter (letter only): "

:: Create a folder named Drivers_Backup on the target drive
:: We will save a copy of all drivers to this location.

md %Target%:\Drivers_Backup
pnputil /export-driver * %Target%:\Drivers_Backup

:: Perform the disk image backup

wbadmin start backup -backuptarget:%Target%: -allcritical -quiet

:: Take ownership of the WindowsImageBackup folder on the target drive

set SourcePath=%Target%:\WindowsImageBackup
C:\windows\system32\takeown /f "%SourcePath%"
icacls "%SourcePath%" /grant %username%:F
C:\windows\system32\takeown /f "%SourcePath%\*.*" /r /d y
icacls "%SourcePath%\*.*" /T /grant %username%:F

cls
echo All operations have been completed.
echo.
pause

:: Backup and Restore Device Drivers in Windows 10 and Windows 11

@Echo Off & cls   
    
(Net session >nul 2>&1)||(PowerShell start """%~0""" -verb RunAs & Exit /B)   
    
Setlocal EnableDelayedExpansion
    
:choice

Cls & Mode CON  LINES=11 COLS=40 & Color 0E & Title Created By FreeBooter
Echo.
Echo.
Echo.
Echo        Export Drivers  (E)?   
Echo.       
Echo        Import Drivers  (I)?
Echo.


Set /p input=:^>

If /i  Not %input%==E (Goto :_Ex) Else (Goto :_Backup)

:_Ex
If /i Not %input%==I  (Goto :choice) Else (Goto :_Restore)


Cls & Mode CON  LINES=20 COLS=40 & Color 0E & Title Created By FreeBooter
:_Backup
    mode con cols=95 lines=5 & color 0E
    Call :BrowseForFolder "Please choose the source folder for to backup drivers" SourceFolder
    If defined SourceFolder (
        echo(
        echo             You chose "!SourceFolder!" as source folder
    ) else (
        echo(
        Color 0C & echo                    The source folder is not defined ... Exiting ......
        Timeout /T 2 /nobreak>nul & exit
    )
Cls & Mode CON  LINES=50 COLS=120 & Color 0E & Title Created By FreeBooter

Dism /online /export-driver /destination:"!SourceFolder!"

Timeout /T 10 /nobreak>nul & exit

    


:_Restore   
    mode con cols=95 lines=5 & color 0E
    
    Call :BrowseForFolder "Please choose the target folder for to restore drivers" TargetFolder
    If defined TargetFolder (
        echo(
        echo             You chose "!TargetFolder!" as Target folder
    ) else (
        echo(
        Color 0C & echo                    The Target folder is not defined ... Exiting ......
        Timeout /T 2 /nobreak>nul & exit
    )
Timeout /T 3 /nobreak>nul
    (
Cls & Mode CON  LINES=50 COLS=120 & Color 0E & Title Created By FreeBooter
    
pnputil /add-driver "!TargetFolder!\*.inf" /subdirs /install /reboot
    )
Timeout /T 10 /nobreak>nul & exit
    
    
    
    :BrowseForFolder
set "psCommand="(new-object -COM 'Shell.Application')^
.BrowseForFolder(0,'%1',0,0).self.path""
for /f "usebackq delims=" %%I in (`powershell %psCommand%`) do set "%2=%%I"
exit /b