Windows 11 2022 Update (22H2) now available

@echo off
cd /d %~dp0
cls

::::::::::::::::::::::::::::::::::::::
:: Windows Image Updater            ::
::                                  ::
:: Version 3.2.0                    ::
::                                  ::
:: Jun 15, 2022 by Hannes Sehestedt ::
::::::::::::::::::::::::::::::::::::::

:: PURPOSE OF THIS SCRIPT
::
:: This script will take one Windows edition in a Windows ISO image and inject Windows
:: updates into it. The updated edition of Windows will be saved to a new file containing
:: just that one edition of Windows. As an example, assume that you have a retail Windows
:: ISO image. This ISO image has multiple editions of Windows such as Win 10 Home, Pro, etc.
:: Each edition of Windows has an index number associated with it.
::
:: For example, on consumer edition ISO images from Microsoft, Windows 10 Pro is index number
:: 6. To get a list of Windows editions and the index number associated with each edition,
:: you can run this command:
::
:: dism /Get-WimInfo /WimFile:C:\Project\ISO_Files\Sources\install.wim
::
:: If located elsewhere, substitute the correct location of the install.wim file in the above command.
::
:: This utility will perform the updates THE RIGHT WAY by updating all elements of the image
:: including not only the cumulative update, but also the SSU (Servicing Stack Update), Safe
:: OS Dynamic Update, Setup Dynamic Update, other updates such as .NET updates and Microcode
:: updates, and will even allow you to add custom scripts to the Windows PE image. However,
:: if you want to update only one item, such as the cumulative update, you can do that as well.
::
:: IMPORTANT: As noted, this script will only update one edition of Windows from an image. If
:: you want to update multiple editions and combine them all into a single image, please
:: message me as noted above. I can provide to you a tool that will allow you to update many
:: Windows editions and combine them into a single image. That same tool also has many other
:: features such as being able to inject drivers into an image, create bootable media, and many
:: other things related to Windows Image Management.
::
:: Please note that it is possible to also add updates such as language packs and other language
:: related components to Windows images. This batch file does not apply any of those updates.


:: SUMMARY OF INSTRUCTIONS
::
:: 1) Read the instructions below to learn how to organize the folders that this project needs.
::
:: 2) Review the "User defined variables" section below and modify as needed.
::
:: 3) Make sure that you have the Windows ADK installed. Only the Deployment Tools from the
::    ADK need to be installed.
::
:: 4) From the ADK, launch an elevated "Deployment and Imaging Tools Environment" and run this
::    batch file from there. This will ensure that tools such as DISM and OSCDIMG can be
::    properly found by this batch file.
::
:: DETAILED INSTRUCTIONS
::
:: Create the following folders before you run this batch file.
::
:: NOTE: The paths below assume the default settings of user defined variables. If you change those variables,
:: Please alter the below paths accordingly.
::
:: Create a folder C:\Project\ISO_Files and copy the entire contents of a Windows ISO image to this folder.
:: NOTE: This location can be changed using the user defined variables below.
::
:: Create the following folders for the Windows updates:
:: NOTE: This location can be changed using the user defined variables below.
::
:: C:\WinUpdates\LCU       <--- Place Latest Cumulative Update in this folder. DON'T use a DYNAMIC version
:: C:\WinUpdates\Other     <--- Place other updates (for example .NET Updates) in this folder
:: C:\WinUpdates\SafeOS_DU <--- Place the latest Safe OS Dynamic Update in this folder
:: C:\WinUpdates\Setup_DU  <--- Place the latest Setup Dynamic Update in this folder
:: C:\WinUpdates\PE_Files  <--- Place any files such as scripts that you want copied to WinPE here.
::
:: NOTE: All items are optional. For example, if you do not have a Safe OS Dynamic Update, simply
::       leave that folder empty.
::
::       The PE_Files noted above can be used to place files that you want to copy to Windows
::       setup. For example, I have a couple of scripts that I want to be available to Windows
::       setup. Any files that you place here will be availale on drive X: during windows
::       setup. Note that X: is the RAM Drive that Windows creates during setup. Since this
::       is just about the first thing setup does, these files will be available very early in
::       setup. IT IS EXTREMEMELY UNLIKELY that you will ever put anything in this folder unless
::       you have a very clear understaning of why you are putting something here.
::
::       If you wish to DELETE files from Windows PE, for example, scripts that you previously added
::       as described in the above paragragh, please search this batch file for the text "delete files
::       from WinPE" and follow the instructions found there. Once again, IT IS EXTREMEMELY UNLIKELY
::       that you will need to do this.
::
::       When downloading updates from the Microsoft Update Catalog, please note that the Safe OS Dynamic
::       Update will include "Windows Safe OS Dysnamic Update" in the "Products" column. The Setup
::       Dynamic Update will simply be called a "Dynamic Update" in this same column.
::
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

::::::::::::::::::::::::::::
:: User defined variables ::
::::::::::::::::::::::::::::

:: Set "IndexNum" to the index number corresponding to the Windows edition you want to update. By
:: default, I specify Index 6 below which is usually Win 10 Pro or Win 11 Pro. To get a list of
:: Windows editions and the index number associated with each edition, you can run this command:
::
:: dism /Get-WimInfo /WimFile:C:\Project\ISO_Files\Sources\install.wim
::
:: If located elsewhere, substitute the correct location of the install.wim file in the above command.

set IndexNum=6

:: Set "ProjectFolder" to the location where the project will be created. Place your extracted ISO
:: image files in a subfolder of this location called \ISO_Files. Example: C:\Project\ISO_Files

set ProjectFolder=d:\My New Project

:: Set "WinUpdates" to location of Windows updates. Under this folder, create the subfolders LCU, Other,
:: SafeOS_DU, Setup_DU, SSU, and PE_Files as described above.

set WinUpdates=D:\Win 11 Updates

:: If you want logging to show what updates actually got installed into your WinRE.WIM, BOOT.WIM,
:: and INSTALL.WIM files, set "EnableLogs" to 1. This will cause two text files for each WIM
:: to be created. The first is created after updates are applied, but before the cleanup of
:: the image is performed. The second is created after cleanup. As an example, after a combined
:: LCU / SSU package is applied, you may see more than one SSU package in the log prior to the
:: cleanup, however, after the cleanup, the older SSU should have been removed. Note that for
:: WinPE four files are created because a pair is created for each of the two indicies that get
:: updated. The files are created in the same folder from which the batch file is run.

set EnableLogs=0

:: Set "NewImageFileName" to the name you want to use for the final ISO image to be created. Make
:: sure to include the .ISO file extension. Spaces in the file name are okay.

set NewImageFileName=Win_Updated.ISO

:::::::::::::::::::::::::::::::::::
:: End of user defined variables ::
:::::::::::::::::::::::::::::::::::


echo Please make certain that you have run this batch file by doing the following:
echo.
echo From the ADK, launch an elevated "Deployment and Imaging Tools Environment" and run this
echo batch file from there. This will ensure that tools such as DISM and OSCDIMG can be
echo properly found by this batch file.
echo.
echo It is also VERY IMPORTANT that prior to running this batch file, you open the file in an
echo editor such as notepad and read the following sections: PURPOSE OF THIS SCRIPT,
echo SUMMARY OF INSTRUCTIONS, DETAILED INSTRUCTIONS. Make certain to set the user defined
echo variables as instructed.
pause

cls
echo ***************************************************************
echo ***************************************************************
echo **                                                           **
echo ** PLEASE BE PATIENT! Applying updates is a lengthy process. **
echo **                                                           **
echo ***************************************************************
echo ***************************************************************
echo.

:: Create the initial directory structure for this project

md "%ProjectFolder%\Mount" > NUL 2>&1
md "%ProjectFolder%\WinRE" > NUL 2>&1
md "%ProjectFolder%\WinRE_Mount" > NUL 2>&1
md "%ProjectFolder%\WinPE" > NUL 2>&1
md "%ProjectFolder%\WinPE_Mount" > NUL 2>&1
md "%ProjectFolder%\Assets" > NUL 2>&1
md "%ProjectFolder%\Temp" > NUL 2>&1
md "%ProjectFolder%\Base" > NUL 2>&1

:: Copy the ISO image files to base folder

echo ****************************************
echo * Copy Windows files to working folder *
echo ****************************************
echo.

robocopy "%ProjectFolder%\ISO_Files" "%ProjectFolder%\Base" /mir  > NUL

:: Mount the install.wim file

echo ****************************************
echo * Mounting main OS image (install.wim) *
echo ****************************************
echo.

DISM /mount-image /imagefile:"%ProjectFolder%\Base\sources\install.wim" /index:%IndexNum% /mountdir:"%ProjectFolder%\Mount" > NUL

:: Update Win RE

echo ******************
echo * Updating WinRE *
echo ******************
echo.
echo    ****************************************
echo    * Updating SSU from combined SSU / LCU *
echo    ****************************************
echo.

copy /B "%ProjectFolder%\Mount\Windows\System32\Recovery\WinRE.wim" "%ProjectFolder%\WinRE" > NUL
DISM /mount-image /imagefile:"%ProjectFolder%\WinRE\WinRE.wim" /index:1 /mountdir:"%ProjectFolder%\WinRE_Mount" > NUL

:: We are now applying the SSU from the combined SSU / LCU package

DISM /Add-Package /Image:"%ProjectFolder%\WinRE_Mount" /PackagePath="%WinUpdates%\LCU" > NUL

:: Applying the Safe OS Dynamic Update

echo    ***********************************
echo    * Applying Safe OS Dynamic Update *
echo    ***********************************
echo.

DISM /Add-Package /Image:"%ProjectFolder%\WinRE_Mount" /PackagePath="%WinUpdates%\SafeOS_DU" > NUL

if %EnableLogs%==1 (
DISM /Get-Packages /image:"%ProjectFolder%\WinRE_Mount" > WinRE_Before_Cleanup.txt
)

:: Cleaning up old files from the image

echo    ************************************
echo    * Cleaning up old files from image *
echo    ************************************
echo.

DISM /Cleanup-Image /Image:"%ProjectFolder%\WinRE_Mount" /StartComponentCleanup > NUL

if %EnableLogs%==1 (
DISM /Get-Packages /image:"%ProjectFolder%\WinRE_Mount" > WinRE_After_Cleanup.txt
)

echo    ********************
echo    * Unmounting image *
echo    ********************
echo.

DISM /Unmount-Image /MountDir:"%ProjectFolder%\WinRE_Mount" /Commit > NUL

echo    *************************
echo    * Exporting WinRE image *
echo    *************************
echo.

DISM /Export-Image /SourceImageFile:"%ProjectFolder%\WinRE\WinRE.wim" /SourceIndex:1 /DestinationImageFile:"%ProjectFolder%\Assets\WinRE.wim" > NUL

:: Update WinPE

echo **************************************
echo * Updating WinPE (boot.wim), index 1 *
echo **************************************
echo.

copy /B "%ProjectFolder%\Base\sources\boot.wim" "%ProjectFolder%\WinPE" > NUL
DISM /mount-image /imagefile:"%ProjectFolder%\WinPE\boot.wim" /index:1 /mountdir:"%ProjectFolder%\WinPE_Mount" > NUL

:: We are now applying the combined SSU / LCU update

echo    *******************************
echo    * Applying combined SSU / LCU *
echo    *******************************
echo.

DISM /Add-Package /Image:"%ProjectFolder%\WinPE_Mount" /PackagePath="%WinUpdates%\LCU" > NUL

if %EnableLogs%==1 (
DISM /Get-Packages /image:"%ProjectFolder%\WinPE_Mount" > WinPE_Index1_Before_Cleanup.txt
)

:: Cleaning up old files from the image

echo    ************************************
echo    * Cleaning up old files from image *
echo    ************************************
echo.

DISM /Cleanup-Image /Image:"%ProjectFolder%\WinPE_Mount" /StartComponentCleanup > NUL

if %EnableLogs%==1 (
DISM /Get-Packages /image:"%ProjectFolder%\WinPE_Mount" > WinPE_Index1_After_Cleanup.txt
)

echo    ********************
echo    * Unmounting image *
echo    ********************
echo.

DISM /Unmount-Image /MountDir:"%ProjectFolder%\WinPE_Mount" /Commit > NUL

echo    **********************************
echo    * Exporting WinPE image, index 1 *
echo    **********************************
echo.

DISM /Export-Image /SourceImageFile:"%ProjectFolder%\WinPE\boot.wim" /SourceIndex:1 /DestinationImageFile:"%ProjectFolder%\Assets\boot.wim" > NUL

echo **************************************
echo * Updating WinPE (boot.wim), index 2 *
echo **************************************
echo.

DISM /mount-image /imagefile:"%ProjectFolder%\WinPE\boot.wim" /index:2 /mountdir:"%ProjectFolder%\WinPE_Mount" > NUL

:: We are now applying the combined SSU / LCU update

echo    *******************************
echo    * Applying combined SSU / LCU *
echo    *******************************
echo.

DISM /Add-Package /Image:"%ProjectFolder%\WinPE_Mount" /PackagePath="%WinUpdates%\LCU" > NUL

:: Copy user files, such as scripts, to WinPE

echo    **************************************
echo    * Copy any user files to WinPE image *
echo    **************************************
echo.

robocopy "%ProjectFolder%\PE_Files" "%ProjectFolder%\WinPE_Mount" *.* /E > NUL

:: If you want to delete files from WinPE, such as scripts you may have added previously, uncommet the
:: line below and change the filename to the name of the file you want to delete. Add additional lines using
:: the same format if needed.

:: del "%ProjectFolder%\WinPE_Mount\MyScript.bat" /Q > NUL

if %EnableLogs%==1 (
DISM /Get-Packages /image:"%ProjectFolder%\WinPE_Mount" > WinPE_Index2_Before_Cleanup.txt
)

:: Cleaning up old files from the image

echo    ************************************
echo    * Cleaning up old files from image *
echo    ************************************
echo.

DISM /Cleanup-Image /Image:"%ProjectFolder%\WinPE_Mount" /StartComponentCleanup > NUL

if %EnableLogs%==1 (
DISM /Get-Packages /image:"%ProjectFolder%\WinPE_Mount" > WinPE_Index2_After_Cleanup.txt
)

:: We are going to delay exporting of the boot.wim index 2 until later so that we can copy files while
:: it is still mounted to the main media. We could this right now, but by delaying it until after the
:: Setup Dynamic Update is applied, we can demonstrate that there are files that are out of sync after
:: all updates, including the Setup Dynamic Update, have been applied.

:: Update install.wim

echo **********************************
echo * Updating main OS (install.wim) *
echo **********************************
echo.

echo    *******************************
echo    * Applying combined SSU / LCU *
echo    *******************************
echo.

:: Note that we apply the combined SSU / LCU twice - once to apply the SSU (if present), and once to apply the LCU.

DISM /Add-Package /Image:"%ProjectFolder%\Mount" /PackagePath="%WinUpdates%\LCU" > NUL
DISM /Add-Package /Image:"%ProjectFolder%\Mount" /PackagePath="%WinUpdates%\LCU" > NUL

echo    ********************************************************
echo    * Move updated winre.wim back into mounted install.wim *
echo    ********************************************************
echo.

move /Y "%ProjectFolder%\Assets\WinRE.wim" "%ProjectFolder%\Mount\Windows\System32\Recovery" > NUL

if %EnableLogs%==1 (
DISM /Get-Packages /image:"%ProjectFolder%\Mount" > MainOS_Before_Cleanup.txt
)

:: Cleaning up old files from the image

echo    ************************************
echo    * Cleaning up old files from image *
echo    ************************************
echo.

DISM /Cleanup-Image /Image:"%ProjectFolder%\Mount" /StartComponentCleanup /ResetBase /ScratchDir:"%ProjectFolder%\Temp" > NUL

if %EnableLogs%==1 (
DISM /Get-Packages /image:"%ProjectFolder%\Mount" > MainOS_After_Cleanup.txt
)

:: Install "Other" Updates (for example, .NET updates)

echo    ****************************************
echo    * Install "Other" updates such as .NET *
echo    * to main OS image (install.wim)       *
echo    ****************************************
echo.

DISM /Add-Package /Image:"%ProjectFolder%\Mount" /PackagePath="%WinUpdates%\Other" > NUL

:: We could copy files from the mounted install.wim now but just as with the boot.wim we will delay doing so
:: until after the Setup Dynamic Update has been applied.

:: Install the setup dynamic update

echo ******************************
echo * Apply Setup Dynamic Update *
echo ******************************
echo.

Expand "%WinUpdates%\Setup_DU\*" -F:* "%ProjectFolder%\Base\Sources" > NUL

echo **************************************************
echo * Copy mismatched files to appropriate locations *
echo **************************************************
echo.

:: The 4 robocopy commands below work around a problem with the Windows update process. Files in the boot.wim have exact duplicate
:: files in other locations on the media. The problem is that the files in the boot.wim get updated, but the other copy of these
:: files do not. This leads to media which may not function properly and from which it may not be possible to install Windows. The
:: robocopy commands below resolve this issue by taking files in the boot.wim that are newer than the duplicates and copying them
:: over the files that were not updated.

robocopy "%ProjectFolder%\winpe_mount" "%ProjectFolder%\Base" setup.exe /xo /xx /xl /r:0 /w:0 /njh /njs > NUL
robocopy "%ProjectFolder%\winpe_mount\sources" "%ProjectFolder%\Base\sources" setup.exe /xo /xx /xl /r:0 /w:0 /njh /njs > NUL
robocopy "%ProjectFolder%\winpe_mount\windows\system32" "%ProjectFolder%\Base\sources" *.* /e /ndl /xo /xx /xl /np /r:0 /w:0 /njh /njs > NUL
robocopy "%ProjectFolder%\mount\windows\system32" "%ProjectFolder%\Base\sources" *.* /e /ndl /xo /xx /xl /np /r:0 /w:0 /njh /njs > NUL

echo ******************************************
echo * Unmounting index 2 of WinPE (boot.wim) *
echo ******************************************
echo.

DISM /Unmount-Image /MountDir:"%ProjectFolder%\WinPE_Mount" /Commit > NUL

echo    **********************************
echo    * Exporting WinPE Image, Index 2 *
echo    **********************************
echo.

DISM /Export-Image /Bootable /SourceImageFile:"%ProjectFolder%\WinPE\boot.wim" /SourceIndex:2 /DestinationImageFile:"%ProjectFolder%\Assets\boot.wim" > NUL

echo ****************************************
echo * Unmounting the Main OS (install.wim) *
echo ****************************************
echo.

DISM /Unmount-Image /MountDir:"%ProjectFolder%\Mount" /Commit > NUL

echo ***************************************
echo * Exporting the Main OS (install.wim) *
echo ***************************************
echo.

DISM /Export-Image /SourceImageFile:"%ProjectFolder%\Base\sources\install.wim" /SourceIndex:%IndexNum% /DestinationImageFile:"%ProjectFolder%\Assets\install.wim" > NUL

echo ******************************************************
echo * Move updated boot.wim and install.wim image folder *
echo * to replace the original files                      *
echo ******************************************************
echo.

move /Y "%ProjectFolder%\Assets\boot.wim" "%ProjectFolder%\Base\Sources" > NUL
move /Y "%ProjectFolder%\Assets\install.wim" "%ProjectFolder%\Base\Sources" > NUL

echo ******************************
echo * Create the final ISO image *
echo ******************************
echo.

oscdimg.exe -m -o -u2 -udfver102 -bootdata:2#p0,e,b"%ProjectFolder%\Base\boot\etfsboot.com"#pEF,e,b"%ProjectFolder%\Base\efi\microsoft\boot\efisys.bin" "%ProjectFolder%\Base" "%ProjectFolder%\%NewImageFileName%" > NUL 2>&1

:: Cleanup the temporary folders.

rd "%ProjectFolder%\Mount" /s /q > NUL
rd "%ProjectFolder%\winre" /s /q > NUL
rd "%ProjectFolder%\winre_mount" /s /q > NUL
rd "%ProjectFolder%\winpe" /s /q > NUL
rd "%ProjectFolder%\winpe_mount" /s /q > NUL
rd "%ProjectFolder%\assets" /s /q > NUL
rd "%ProjectFolder%\temp" /s /q > NUL
rd "%ProjectFolder%\Base" /s /q > NUL

echo Done! The ISO image has been saved as "%ProjectFolder%\Win_Updated.iso"
echo.