Installation and Upgrade Create Windows 11 Bootable USB Installation Media

echo on
REM =========================================================================================
REM ======BIG WARNING - FIRST TWO PARAMETERS MUST BE CONFIGURED CORRECTLY ===================
REM =========================================================================================

REM SET DRIVE NUMBER OF MOUNTED USB DRIVE - WARNING THIS MUST BE CORRECT.
REM IT IS USUALLY LAST ONE IN DRIVE NUMBER LIST
REM VERY BIG WARNING - IF  YOU CHOOSE WRONG DRIVE YOU WILL WIPE IT!!!
REM SET TO 99 INITIALLY TO PREVENT RISK OF ACCIDENTAL DELETION
set USBDRIVE=99

REM  SET DRIVE LETTER OF MOUNTED DRIVE - IF DRIVE LETTER IS WRONG, BATCH WILL NOT WORK.
set ISODRIVE=I

REM =========================================================================================
REM ================== ALL OTHER PARAMETERS CAN NOMRALLY BE LEFT ALONE ======================
REM ============== ONLY CHANGE DRIVE LETTERS IF NEEDED E.G. USED ELSEWHERE ==================
REM =========================================================================================

REM SET DRIVE OF TEMPORARY FILES
set USBTDRV=C


REM SET DRIVE LETTER OF FAT32 PARTITION
set FAT32=Q

REM SET DRIVE LETTER OF EXFAT PARTITION
set EXFAT=R

REM CREATE WORKING DIRECTORY
%USBTDRV%:
cd\
rd usbcreate /s /q
md usbcreate
pause

REM LIST DISKS AND CHECK USB DRIVE NUMBER IS SET
echo LIST DISK > %USBTDRV%:\usbcreate\listdisk.txt
CLS
diskpart /s %USBTDRV%:\usbcreate\listdisk.txt
IF %USBDRIVE%==99 goto :NOTSET
pause
GOTO :CONT1
:NOTSET
echo off
echo.
echo XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
echo X                                                            X
echo X YOU HAVE NOT SET DRIVE NUMBER OF USB DRIVE                 X
echo X IT IS USUALLY LAST ONE IN THE ABOVE LIST BUT CAN DIFFER    X
echo X                                                            X
echo X MAKE SURE USB DRIVE IS PLUGGED IN                          X
echo X                                                            X
echo X WARNING - MAKE SURE DRIVE NUMBER IS RIGHT                  X
echo X OR ELSE YOU COULD WIPE WRONG DRIVE                         X
echo X                                                            X
echo X I ACCEPT NO RESPONSIBILITY FOR ANY MISTAKES                X
echo X YOU HAVE BEEN WARNED!!!!!                                  X
echo X                                                            X
echo XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
PAUSE
GOTO :ENDPROG
:CONT1

REM CREATE EI.CFG
echo [CHANNEL] > %USBTDRV%:\usbcreate\ei.cfg
echo Retail >> %USBTDRV%:\usbcreate\ei.cfg

REM FORMAT USB DRIVE
echo select disk %USBDRIVE% > %USBTDRV%:\usbcreate\formatdisk.txt
echo clean >> %USBTDRV%:\usbcreate\formatdisk.txt
echo convert mbr >> %USBTDRV%:\usbcreate\formatdisk.txt
echo create partition primary size=2000 >> %USBTDRV%:\usbcreate\formatdisk.txt
echo create partition primary >> %USBTDRV%:\usbcreate\formatdisk.txt
echo select partition 1 >> %USBTDRV%:\usbcreate\formatdisk.txt
echo format fs=fat32 quick >> %USBTDRV%:\usbcreate\formatdisk.txt
echo assign letter=Q >> %USBTDRV%:\usbcreate\formatdisk.txt
echo active >> %USBTDRV%:\usbcreate\formatdisk.txt
echo select partition 2 >> %USBTDRV%:\usbcreate\formatdisk.txt
echo format fs=exFat quick >> %USBTDRV%:\usbcreate\formatdisk.txt
echo assign letter=R >> %USBTDRV%:\usbcreate\formatdisk.txt
echo exit >> %USBTDRV%:\usbcreate\formatdisk.txt
diskpart /s %USBTDRV%:\usbcreate\formatdisk.txt
pause
REM CREATE DRIVE
cd \usbcreate
md baseiso
xcopy %ISODRIVE%:\*.* %USBTDRV%:\usbcreate\baseiso\ /s /y

REM COPY ALL FILES TO EXFAT FOLDER
label %EXFAT%:USB-EXFAT
%USBTDRV%:
cd \usbcreate\baseiso
xcopy *.* %EXFAT%:\ /s /y
xcopy %USBTDRV%:\usbcreate\ei.cfg %EXFAT%:\sources /s /y

REM COPY ALL FILES EXCEPT THOSE IN SOURCES FOLDER (DELETE FROM BASEISO)
label %FAT32%:USB-FAT32
del %USBTDRV%:\usbcreate\baseiso\sources\*.* /q
cd %USBTDRV%:\usbcreate\baseiso
rd sources /s /q

%USBTDRV%:
cd \usbcreate\baseiso
xcopy *.* %FAT32%:\ /s /y
cd %FAT32%:\
md sources
xcopy %EXFAT%:\sources\boot.wim %FAT32%:\sources\boot.* /s /y

REM DELETE WORKING DIRECTORY
%USBTDRV%:
cd\
rd usbcreate /s /q
:ENDPROG

pause