Solved How do I detect windows 11 with version command in batch file?

andrew129260 · Jan 26, 2024

With windows 10 being marked as 10, like this:

Batch:

if "%version%" == "10.0" goto ver_Win10updatefix

I tried doing this for windows 11 and it did not work:

Batch:

if "%version%" == "10.0.22000.0" goto ver_Win11updatefix

In short, I am trying to detect the windows version (and more ideally) the feature pack of windows to run certain commands from my batch file and I am having trouble getting it to detect the difference between windows 10 and windows 11.

I would prefer something that works with batch as my entire utility is made in it, and to jump out to que powershell would be a pain. I am sure it's easily doable and I am just missing something. Or perhaps there is a better way than using if version?

Let me know.

Thanks in advance!

Wynona · Jan 26, 2024

andrew129260 said:
With windows 10 being marked as 10, like this:

Batch:

if "%version%" == "10.0" goto ver_Win10updatefix

I tried doing this for windows 11 and it did not work:

Batch:

if "%version%" == "10.0.22000.0" goto ver_Win11updatefix

In short, I am trying to detect the windows version (and more ideally) the feature pack of windows to run certain commands from my batch file and I am having trouble getting it to detect the difference between windows 10 and windows 11.

Thanks

I'm not real sure, but I think I've seen that some Windows 11 commands still show Windows 10.

pseymour · Jan 26, 2024

Batch:

C:\Users\Me>for /f "tokens=4 delims=[] " %a in ('ver') do @echo %a

10.0.22631.3007

or

Batch:

C:\Users\Me>for /f "tokens=4 delims=[] " %a in ('ver') do @set version=%a

C:\Users\Me>echo %version%

10.0.22631.3007

Of course, in a batch script, you have to double up the % in the for command (%%a instead of %a).

Windows 11 builds are 22000 and up; Windows 10 is always less than that.

FreeBooter · Jan 26, 2024

Try Systeminfo command.

hdmi · Jan 26, 2024

Batch:

@echo off
for /f "tokens=4 delims=[] " %%a in ('ver') do set v=%%a
set w=%v:10.0.=%
if %v% == %w% goto skip
set x=.%w:*.=%
setlocal enabledelayedexpansion
set w=!w:%x%=!
if !w! lss 22000 goto skip
   endlocal
   echo Windows 11
   pause
goto:eof
:skip
   endlocal
   echo not Windows 11
   pause
goto:eof

andrew129260 · Jan 27, 2024

Thanks everyone for the suggestions, I'll take a look at them and try them out as soon as I have time

andrew129260 · Jan 27, 2024

FreeBooter said:
Try Systeminfo command.

Thanks freebooter, I went with this and it worked great!

See code below:

Batch:

:winupdatefixmenu
CLS
ECHO                                Windows Update Fix It
ECHO ______________________________________________________________________________
ECHO Checking Windows Version for the Correct fix...
timeout /t 3 /nobreak >nul
REM Check Windows Version
systeminfo | find "OS Name" > %TEMP%\osname.txt
FOR /F "usebackq delims=: tokens=2" %%i IN (%TEMP%\osname.txt) DO set vers=%%i

echo %vers% | find "Windows 10" > nul
if %ERRORLEVEL% == 0 goto ver_Win10updatefix

echo %vers% | find "Windows 11" > nul
if %ERRORLEVEL% == 0 goto ver_Win11updatefix

:ver_Win10updatefix
ECHO Detected OS Version: Windows 10
ECHO Launching Fix...
timeout /t 3 /nobreak >nul
"%~d0\programs\computersecurity\computersecurity\windowsfixes\windowsupdatefixes\W10wipeandResetwindowsupdate.bat"
ECHO.
GOTO Windowsfixes


:ver_Win11updatefix
ECHO Detected OS Version: Windows 11
ECHO Launching Fix...
timeout /t 3 /nobreak >nul
"%~d0\programs\computersecurity\computersecurity\windowsfixes\windowsupdatefixes\W11wipeandResetwindowsupdate.bat"
ECHO.
GOTO Windowsfixes

FreeBooter · Jan 27, 2024

You are very welcome!

Try3 · Jan 28, 2024

andrew129260 said:
How do I detect windows 11 with version command in batch file

ReportOSVersion.bat [post #8] - TenForums
The batch file works in both Windows 10 & Windows 11.

All the best,
Denis

Ed Tittel · Jan 29, 2024

@denis: the script resets the prompt to a simple >. I changed it to remove the pause at the end, and added SET PROMPT=$P$G and that restored things to normal defaults. Just sayin' ...
Cheers!
-Ed-

Try3 · Jan 30, 2024

Ed Tittel said:
the script resets the prompt to a simple >

Ed,

Yes, it does. That is achieved by the line
prompt $g
and it applies only to the current session [i.e. the batch file running] so there is no need to change anything, no defaults are affected.
- Do note that setting the prompt does not require a Set command.
- You could use a Setx command if you wanted to change the default Command window prompt.

All the best,
Denis

Solved How do I detect windows 11 with version command in batch file?

Well-known member

My Computers

Well-known member

My Computers

recently made a series of cow puns

My Computer

Well-known member

My Computer

Jack of all trades – master of none

My Computers

Well-known member

My Computers

Well-known member

My Computers

Well-known member

My Computer

Well-known member

My Computer

Well-known member

My Computer

Well-known member

My Computer

Similar threads