Solved How do I detect windows 11 with version command in batch file?

if "%version%" == "10.0" goto ver_Win10updatefix

if "%version%" == "10.0.22000.0" goto ver_Win11updatefix

C:\Users\Me>for /f "tokens=4 delims=[] " %a in ('ver') do @echo %a

10.0.22631.3007

C:\Users\Me>for /f "tokens=4 delims=[] " %a in ('ver') do @set version=%a

C:\Users\Me>echo %version%

10.0.22631.3007

@echo off
for /f "tokens=4 delims=[] " %%a in ('ver') do set v=%%a
set w=%v:10.0.=%
if %v% == %w% goto skip
set x=.%w:*.=%
setlocal enabledelayedexpansion
set w=!w:%x%=!
if !w! lss 22000 goto skip
   endlocal
   echo Windows 11
   pause
goto:eof
:skip
   endlocal
   echo not Windows 11
   pause
goto:eof

:winupdatefixmenu
CLS
ECHO                                Windows Update Fix It
ECHO ______________________________________________________________________________
ECHO Checking Windows Version for the Correct fix...
timeout /t 3 /nobreak >nul
REM Check Windows Version
systeminfo | find "OS Name" > %TEMP%\osname.txt
FOR /F "usebackq delims=: tokens=2" %%i IN (%TEMP%\osname.txt) DO set vers=%%i

echo %vers% | find "Windows 10" > nul
if %ERRORLEVEL% == 0 goto ver_Win10updatefix

echo %vers% | find "Windows 11" > nul
if %ERRORLEVEL% == 0 goto ver_Win11updatefix

:ver_Win10updatefix
ECHO Detected OS Version: Windows 10
ECHO Launching Fix...
timeout /t 3 /nobreak >nul
"%~d0\programs\computersecurity\computersecurity\windowsfixes\windowsupdatefixes\W10wipeandResetwindowsupdate.bat"
ECHO.
GOTO Windowsfixes


:ver_Win11updatefix
ECHO Detected OS Version: Windows 11
ECHO Launching Fix...
timeout /t 3 /nobreak >nul
"%~d0\programs\computersecurity\computersecurity\windowsfixes\windowsupdatefixes\W11wipeandResetwindowsupdate.bat"
ECHO.
GOTO Windowsfixes